Re: Re: Pitch-shift

by joachim heintz :: Rate this Message:

... and if you need a simple example:

<CsoundSynthesizer>
<CsOptions>
-odac
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 16
nchnls = 1
0dbfs = 1

instr 1
ifftsize = 1024
ioverlap = ifftsize / 4
iwinsize = ifftsize
iwinshape = 1; von-Hann window
Sfile = "fox.wav"
ain soundin Sfile
fftin pvsanal ain, ifftsize, ioverlap, iwinsize, iwinshape; fft-
analysis of the audio-signal
fftscale pvscale fftin, p4, p5, p6; scale
aout pvsynth fftscale; resynthesis
out aout
endin

</CsInstruments>
<CsScore>
i 1 0 3 1 0 1; original sound
i 1 3 3 1.5 0 2; fifth higher without ...
i 1 6 3 1.5 1 2; ... and with different ...
i 1 9 3 1.5 2 5; ... kinds of formant preservation
e
</CsScore>
</CsoundSynthesizer>

Best -

joachim

Am 30.06.2009 um 20:02 schrieb Victor.Lazzarini@...:

> Try pvscale.
>
> ----- Original Message -----
> From: Charles Gran <chasgran@...>
> Date: Tuesday, June 30, 2009 5:11 pm
> Subject: [Csnd] Pitch-shift
> To: csound@...
>
> > I would like to apply pitch shifting to a real-time audio signal
> > (-iadc). I have been able to use harmon and am wondering
> > if there are
> > other options for real-time performance.
> >
> > Charles
> >
> >
> > Send bugs reports to this list.
> > To unsubscribe, send email sympa@... with body
> > "unsubscribe csound"
>
> Dr Victor Lazzarini, Senior Lecturer, Dept. of Music,
> National University of Ireland, Maynooth

Send bugs reports to this list.
To unsubscribe, send email sympa@... with body "unsubscribe csound"

« Return to Thread: Pitch-shift